unsafe 코드를 가진 애플리케이션은 PEVerify으로 체크할 때 실패합니다. 여러분은 이 상태를 중간 마이그레이션 결과로서 그대로 수용할 수도 있겠지만, 최종 목표로서 100% safe한 .NET 애플리케이션을 원할 수 있습니다.

- {$UNSAFECODE ON} 컴파일러 디렉티브와 Create 생성자 및 Execute 메소드에 있는 2개의 unsafe 키워드도 삭제한 후 unsafe한 코드 부분들을 수정할 준비를 합시다.

첫번째 문제(다른 모든 문제를 발생시키죠)는, 포인터 타입을 선언한 것입니다. TSortArray 선언을 "array of integer"으로 치환할 수 있습니다. 코드가 .NET 뿐만 아니라 Win32 컴파일러에서도 컴파일될 수 있도록 하고 싶다면 원래의 코드와 새 코드를 구분하기 위해 컴파일러 디렉티브를 사용할 수 있습니다.

- TSortArray의 타입 선언을 array of integer로 바꾸고 다음과 같이 이전의 WIN32 선언과 새 .NET 선언을 구별하기 위한 컴파일러 디렉티브를 사용합니다.

{$IFDEF WIN32}
  PSortArray = ^TSortArray;
  TSortArray = array[0..MaxInt div SizeOf(Integer) - 1] of Integer;
{$ELSE}
  TSortArray = array of Integer;
{$ENDIF}

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이번에는, FSortArray의 선언에 대한 에러 메시지가 나타날 것입니다. 이제는 PSortArray가 알 수 없는 타입이기 때문입니다. .NET 환경에서는 FSortArray를 TSortArray 타입으로 선언할 수 있습니다. Using the .NET compiler, we can simply define FSortArray as being of type TSortArray.

- FSortArray 필드의 타입을 PSortArray에서 TSortArray로 바꿉니다. 만약 WIN32와 .NET 양쪽 모두에서 컴파일되도록 하기 위해 컴파일러 디렉티브를 사용하려 한다면, 다음과 같이 될 것입니다.

  TSortThread = class(TThread)
  private
    FBox: TPaintBox;
    FSortArray: {$IFDEF WIN32}PSortArray{$ELSE}TSortArray{$ENDIF};

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이번에는 create 생성자에서 @ 연산자가 사용될 수 없다는 에러가 날 것입니다.

- 다음과 같이 Create 생성자에서 @ 연산자를 제거합시다.

constructor TSortThread.Create(Box: TPaintBox; var SortArray: array of Integer);
begin
  inherited Create(False);
  FBox := Box;
  FSortArray := {$IFDEF WIN32}@{$ENDIF}SortArray;
  FSize := High(SortArray) - Low(SortArray) + 1;
  FreeOnTerminate := True;
end;

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

마지막 에러는 Execute 메소드에서 ^ 연산자를 사용한 것에 대한 것입니다. .NET 컴파일러를 이용하는 경우 위에서처럼 제거할 수 있습니다. 다음과 같이 바꿉니다.

procedure TSortThread.Execute;
begin
//  Sort(Slice(FSortArray^, FSize));
  Sort(FSortArray{$IFDEF WIN32}^{$ENDIF});
end;

*Sort는 인자를 var 형태로 받으므로 여기서 전체 정수 배열을 전달하는 데 대해서는 걱정할 필요가 없습니다. (otherwise it would make sense to see if you could add a const keyword).

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 unsafe code 에러는 모두 사라졌고 platform specific 워닝만 남은 상태입니다. 이제 이 예제는 VCL.NET을 이용하는 네이티브, 세이프, 매니지드 .NET 실행파일이 된 것입니다. Threads 데모에서는 빠르지만 깔끔하지 못한 마이그레이션을 보여드렸습니다. 다음으로 완전히 safe하고 매니지드한 마이그레이션 방식을 보여드리겠습니다.

먼저 데이터베이스가 정확한 위치를 가리키고 있는지부터 확인합니다. 이것은 애플리케이션을 처음 컴파일하려고 하기 전에 하는 것이 좋습니다. 일단 데이터베이스 연결이 정확하게 설정되고 나면 소스 코드의 마이그레이션에만 집중할 수 있게 됩니다.

- 프로젝트 매니저에서 DataMod.pas 파일을 더블클릭하여 데이터모듈을 엽니다.

데이터모듈은 데이터 액세스 기술로 인터베이스 익스프레스 컴포넌트들을 이용하고 있으며 다음의 그림처럼 디자인되어 있습니다.

디자인타임 VCL.NET 데이터모듈

데이터베이스 컴포넌트를 다시 설정할 필요가 있습니다. 이 컴포넌트는 오른쪽 아래편에 있습니다.

- 데이터모듈의 데이터베이스 컴포넌트(TIBDatabase 타입)를 클릭합니다.

- 데이터베이스 컴포넌트를 오른쪽 클릭하면 팝업메뉴가 나타나는데, 여기서 인터베이스익스프레스의 버전(9.09)을 볼 수 있고 또 데이터베이스 에디터를 선택할 수 있습니다. 데이터베이스 에디터를 선택하면 다음과 같은 다이얼로그가 나타날 것입니다.

데이터베이스 컴포넌트 에디터

데이터베이스의 패스가 D: 드라이브로 되어 있을 겁니다. 이걸 C: 드라이브로, 그리고 Borland 대신 Common Files로 바꾸어야 할 겁니다. 제 기본 설치대로라면, mastsql.gdb 파일은 C:\Program Files\Common Files\Borland Shared\Data\mastsql.gdb 위치에 있습니다. 여러분의 설정은 또 다를 수도 있죠.

- Test 버튼을 클릭하여 mastsql.gdb 데이터베이스로 연결이 되는지 확인합니다. 연결이 안된다면, that mastsql.gdb 파일이 지정된 경로에 존재하는지 확인하고 인터베이스가 실행중인지도 확인하십시오.

- Test 버튼을 눌렀을 때 연결이 성공하면 데이터베이스 컴포넌트 에디터를 닫습니다.

*VCL 프로젝트를 .NET으로 마이그레이션할 때마다 먼저 데이터모듈의 데이터 액세스 컴포넌트가 정확한 데이터베이스를 가리키고 있는지 확인해야 할 것입니다. 대부분의 VCL 데이터 액세스 컴포넌트는 VCL.NET 버전이 있습니다만, .NET에는 SQL 링크 지원이 없으므로 SQL 링크 기반의 프로젝트는 dbExpress나 dbGo for ADO, InterBaseExpress, 혹은 다른 VCL.NET 데이터 액세스 기술로 마이그레이션해야 합니다.

데이터모듈과 특히 데이터 액세스 연결을 확인하고 나면 프로젝트를 처음으로 컴파일해볼 수 있습니다.

- Shift+F2 키를 눌러 모든 파일을 저장합니다.

- Ctrl+F9 키를 눌러 mastapp 프로젝트를 처음으로 컴파일합니다.

다음과 같이 17개의 워닝과 1개의 에러가 발생할 것입니다.

  [Warning] mastapp.dpr(23): W1005 Unit 'Borland.Vcl.Forms' is specific to a platform
  [Warning] MAIN.PAS(6): W1005 Unit 'Borland.Vcl.Windows' is specific to a platform
  [Warning] MAIN.PAS(6): W1005 Unit 'Borland.Vcl.Messages' is specific to a platform
  [Warning] MAIN.PAS(6): W1005 Unit 'Borland.Vcl.Graphics' is specific to a platform
  [Warning] MAIN.PAS(6): W1005 Unit 'Borland.Vcl.Controls' is specific to a platform
  [Warning] MAIN.PAS(7): W1005 Unit 'Borland.Vcl.Forms' is specific to a platform
  [Warning] MAIN.PAS(7): W1005 Unit 'Borland.Vcl.Dialogs' is specific to a platform
  [Warning] MAIN.PAS(7): W1005 Unit 'Borland.Vcl.Buttons' is specific to a platform
  [Warning] MAIN.PAS(7): W1005 Unit 'Borland.Vcl.StdCtrls' is specific to a platform
  [Warning] MAIN.PAS(7): W1005 Unit 'Borland.Vcl.Menus' is specific to a platform
  [Warning] MAIN.PAS(7): W1005 Unit 'Borland.Vcl.ExtCtrls' is specific to a platform
  [Warning] DataMod.pas(8): W1005 Unit 'Borland.Vcl.Windows' is specific to a platform
  [Warning] DataMod.pas(8): W1005 Unit 'Borland.Vcl.Messages' is specific to a platform
  [Warning] DataMod.pas(8): W1005 Unit 'Borland.Vcl.Graphics' is specific to a platform
  [Warning] DataMod.pas(8): W1005 Unit 'Borland.Vcl.Controls' is specific to a platform
  [Warning] DataMod.pas(8): W1005 Unit 'Borland.Vcl.Forms' is specific to a platform
  [Warning] DataMod.pas(8): W1005 Unit 'Borland.Vcl.Dialogs' is specific to a platform
  [Fatal Error] DataMod.pas(9): F1026 File not found: 'VarUtils.dcuil'

워닝들은 플랫폼에 의존적인 VCL.NET 유닛들을 uses 하고 있다는 사실을 알려줄 뿐이므로 무시할 수 있습니다. 이런 platform specific 워닝들을 피하려면 뜨지 않도록 설정할 수도 있습니다.

- Project | Options 메뉴를 클릭하고 Project Options로 갑니다. 다음 그림처럼 Compiler Messages 카테고리에서 "Platform Unit" 워닝의 체크를 빼면 됩니다. 이제부터는 프로젝트를 컴파일할 때마다 이 워닝들을 다시 보지 않게 됩니다.

프로젝트 옵션 - 워닝 메시지들

- Project | Build mastapp 메뉴를 선택하거나 Shift+F9 키를 눌러 빌드합니다. 앞에서 봤던 17개의 워닝은 나타나지 않겠지만 에러는 그대로 있을 것입니다.

  [Fatal Error] DataMod.pas(9): F1026 File not found: 'VarUtils.dcuil'

이 에러는 VarUtils 유닛이 VCL.NET에는 존재하지 않기 때문에 발생한 것입니다(Variants 유닛에 통합되었습니다). 따라서 우리는 VarUtils 유닛을 uses 절에서 삭제할 수 있습니다.

- DataMod.pas의 interface 섹션의 uses 절에서 VarUtils를 삭제합니다.

*여러분의 프로젝트가 Win32에서도 그대로 컴파일 가능하도록 유지하고 싶다면, uses 절에서 VarUtils 유닛을 그냥 삭제하는 대신 {$IFDEF WIN32} .... {$ENDIF} 블럭 안에 둘 수 있습니다.

- 만약 IFDEF를 쓰기로 결정했다면 uses 절을 다음과 같이 수정하십시오.

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DB, IBQuery, IBCustomDataSet, IBTable, IBDatabase, IB, Variants
  {$IFDEF WIN32}, VarUtils {$ENDIF};

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트와 2개의 에러가 나올 것입니다.

[Error] EDCUST.PAS(54): E2010 Incompatible types: 'Variant' and 'Double'
[Fatal Error] BrCstOrd.pas(48): F2063 Could not compile used unit 'EDCUST.PAS'

'incompatible type' 워닝의 원인이 되는 코드는 다음과 같습니다.

procedure TEdCustForm.Edit(CustNo: Double);
begin
  MastData.Cust.Open;
  MastData.Cust.Locate('CustNo', CustNo, []);
  ShowModal;
end;

이 에러 메시지는 MastData.Cust.Locate 메소드의 CustNo 인자와 관련된 것입니다. 이 변수는 Double 타입인데, 해당 메소드에서 요구되는 타입은 Variant 타입입니다. 그 자체로는 문제가 없지만, 컴파일하기 위해서는 Variants 유닛이 uses 절에 추가되어야 합니다.

- Edcust.pas 유닛의 implementation 섹션의 uses 절에 Variants 유닛을 추가합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트와 1개의 에러가 남았습니다.

[Fatal Error] EDORDERS.PAS(10): F1026 File not found: 'DBLookup.dcuil'

DBLookup 유닛도 VCL.NET에 존재하지 않는 거 같군요. 안심하고 지워도 됩니다.

- Edorders.pas 유닛의 interface 섹션의 uses 절에서 DBLookup 유닛을 제거합니다.

*여러분의 프로젝트가 Win32에서도 그대로 컴파일 가능하도록 유지하고 싶다면, uses 절에서 DBLookup 유닛을 그냥 삭제하는 대신 {$IFDEF WIN32} .... {$ENDIF} 블럭 안에 둘 수 있습니다.

- 만약 IFDEF를 쓰기로 결정했다면 uses 절을 다음과 같이 수정하십시오.

uses
  SysUtils, Windows, Messages, Classes, Graphics, Controls,
  Dialogs, Forms, StdCtrls, DBGrids, DBCtrls, DB,
  Buttons, Grids, {$IFDEF WIN32} DBLookup, {$ENDIF} ExtCtrls, Mask;

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트와 4개의 에러가 나올 것입니다.

[Error] SrchDlg.pas(54): E2010 Incompatible types: 'Variant' and 'Double'
[Error] SrchDlg.pas(64): E2010 Incompatible types: 'Variant' and 'Double'
[Error] SrchDlg.pas(98): E2010 Incompatible types: 'Variant' and 'TCaption'
[Fatal Error] EDORDERS.PAS(76): F2063 Could not compile used unit 'SrchDlg.pas'

앞의 세가지 문제는 이전에 봤던 에러와 매우 비슷합니다. uses 절에 Variants 유닛을 추가함으로써 해결되었었죠.

- SrchDlg.pas 유닛의 implementation 섹션의 uses 절에 Variants 유닛을 추가합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트와 1개의 워닝, 그리고 2개의 에러가 나올 것입니다.

[Error] EDORDERS.PAS(105): E2010 Incompatible types: 'Variant' and 'Double'
[Warning] EDORDERS.PAS(229): W1050 WideChar reduced to byte char in set expressions
[Fatal Error] BrCstOrd.pas(48): F2063 Could not compile used unit 'EDORDERS.PAS'

위의 에러는 이제 금방 알아볼 것입니다. 워닝은 나중에 해결하겠습니다. 지금은 컴파일러 에러를 해결하는 데만 집중합시다.

- Edorders.pas 유닛의 implementation 섹션의 uses 절에 Variants 유닛을 추가합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트, 1개의 워닝, 3개의 에러가 나올 것입니다.

- BrCstOrd.pas 유닛의 implementation 섹션의 uses 절에 Variants 유닛을 추가합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트, 1개의 워닝, 1개의 에러가 나올 것입니다.

- Edparts.pas 유닛의 interface 섹션 uses 절에서 DBLookup을 제거하거나, 다음과 같이 DBLookup을 {$IFDEF WIN32} 블럭으로 감쌉니다.

uses
  SysUtils, Windows, Messages, Classes, Graphics, Controls,
  Forms, Dialogs, DB, StdCtrls, ExtCtrls, Mask, DBCtrls,
  {$IFDEF WIN32} DBLookup, {$ENDIF} Buttons;

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트, 1개의 워닝, 2개의 에러가 나올 것입니다.

- Edparts.pas 유닛의 implementation 섹션의 uses 절에 Variants 유닛을 추가합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트, 1개의 워닝, 2개의 에러가 나올 것입니다.

- Brparts.pas 유닛의 implementation 섹션의 uses 절에 Variants 유닛을 추가합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제 3개의 힌트, 1개의 워닝, 1개의 페이털 에러가 나올 것입니다.

  [Hint] DataMod.pas(244): H2443 Inline function 'ExpandFileName' has not been expanded
  because unit 'System.IO' is not specified in USES list
  [Hint] DataMod.pas(743): H2443 Inline function 'FileExists' has not been expanded because
  unit 'System.IO' is not specified in USES list
  [Hint] DataMod.pas(748): H2443 Inline function 'ExtractFileName' has not been expanded
  because unit 'System.IO' is not specified in USES list
  [Warning] EDORDERS.PAS(229): W1050 WideChar reduced to byte char in set expressions
  [Fatal Error] CustRpt.pas(6): F1026 File not found: 'Quickrpt.dcuil'

이 시점에서, 델파이 2005 VCL 디자이너가 CustRpt 유닛을 보여주려 할 때 몇몇 속성을 찾을 수 없다는 디자인타임 에러 다이얼로그도 나타날 것입니다.

문제는 CustRpt.pas 유닛에서 필요한 Quickrpt.dcuil 유닛을 찾을 수 없기 때문에 발생했습니다. QuickReport의 .NET 버전은 델파이 2005에 포함되어 있지 않습니다. 이 기능을 마이그레이션하기 위해 추천되는 방법들 중 한가지는 Rave Reports를 이용하는 것입니다. 혹은 QuickReports의 .NET 버전을 찾아보거나, 다른 레포팅 관련 프레임워크를 찾아볼 수도 있습니다.

Reporting is left as exercise for the reader, 하지만 우리는 레포팅 기능을 제외하고라도 일단 프로젝트를 컴파일해야 합니다.

- Project | View Source 메뉴를 클릭하여 프로젝트 소스(mastapp.dpr)를 열고, uses 절에서 QuickReports의 유닛들을 찾습니다(이들 유닛은 TQuickRep 타입입니다). 그리고 다음과 같이 주석으로 처리합니다.

uses
  Forms,
  Main in 'MAIN.PAS' {MainForm},
  Brparts in 'BRPARTS.PAS' {BrPartsForm},
  QryCust in 'QryCust.pas' {QueryCustDlg},
  Edparts in 'EDPARTS.PAS' {EdPartsForm},
  BrCstOrd in 'BrCstOrd.pas' {BrCustOrdForm},
  Edcust in 'EDCUST.PAS' {EdCustForm},
  Edorders in 'EDORDERS.PAS' {EdOrderForm},
  SrchDlg in 'SrchDlg.pas' {SearchDlg},
  Splash in 'SPLASH.PAS' {SplashForm},
  Pickdate in 'PICKDATE.PAS' {BrDateForm},
  About in 'ABOUT.PAS' {AboutBox},
  Pickrep in 'PICKREP.PAS' {PickRpt},
//CustRpt in 'CustRpt.pas' {CustomerByInvoiceReport: TQuickRep},
//OrderRpt in 'OrderRpt.pas' {OrdersByDateReport: TQuickRep},
//InvcRpt in 'InvcRpt.pas' {InvoiceByOrderNoReport: TQuickRep},
  PickInvc in 'PickInvc.pas' {PickOrderNoDlg},
  DataMod in 'DataMod.pas' {MastData: TDataModule};

소스 라인을 주석으로 처리하는 빠른 방법은 Ctrl+/ 키를 누르는 것입니다. 이 핫키는 주석되지 않은 코드를 주석으로 토글해주고 다음 라인으로 커서를 옮깁니다. 따라서 3 라인 전체를 빠르게 주석 처리할 수 있습니다.

*여러 라인을 블럭으로 선택한 후 Ctrl+/ 키를 누르면 전체 블럭이 한번에 주석 처리됩니다.

- 프로젝트 소스 파일의 가장 아래쪽으로 이동하여, QuickReports 폼을 생성하는 세개의 CreateForm 코드를 찾습니다. 블럭으로 선택한 다음 Ctrl+/ 키를 눌러 다음과 같이 주석 처리합니다.

begin
  Application.Initialize;
  SplashForm := TSplashForm.Create(Application);
  SplashForm.Show;
  SplashForm.Update;
  Application.Title := 'Marine Adventures Order Entry';
  Application.HelpFile := 'MASTAPP.HLP';
  Application.CreateForm(TMainForm, MainForm);
  Application.CreateForm(TBrPartsForm, BrPartsForm);
  Application.CreateForm(TQueryCustDlg, QueryCustDlg);
  Application.CreateForm(TEdPartsForm, EdPartsForm);
  Application.CreateForm(TBrCustOrdForm, BrCustOrdForm);
  Application.CreateForm(TEdCustForm, EdCustForm);
  Application.CreateForm(TEdOrderForm, EdOrderForm);
  Application.CreateForm(TSearchDlg, SearchDlg);
  Application.CreateForm(TBrDateForm, BrDateForm);
  Application.CreateForm(TAboutBox, AboutBox);
  Application.CreateForm(TPickRpt, PickRpt);
//  Application.CreateForm(TCustomerByInvoiceReport, CustomerByInvoiceReport);
//  Application.CreateForm(TOrdersByDateReport, OrdersByDateReport);
//  Application.CreateForm(TInvoiceByOrderNoReport, InvoiceByOrderNoReport);
  Application.CreateForm(TPickOrderNoDlg, PickOrderNoDlg);
  Application.CreateForm(TMastData, MastData);
  SplashForm.Hide;
  SplashForm.Free;
  Application.Run;
end.

이것으로 끝난 것은 아닙니다. QuickReports를 이용하는 유닛들은 이 프로젝트의 다른 곳에서도 이용되고 있기 때문입니다. 이런 코드들을 모두 찾아서 주석으로 처리해야 합니다.

- Search | Find 메뉴를 클릭하고 CustRpt를 검색합니다(이 유닛은 다른 유닛들의 uses 절에도 있으므로 제거해야 합니다).

델파이 2005 Find in Files

*검색 결과가 파일별로 그룹되어 트리뷰에 나타나는 것을 주목하십시오. 검색 결과로 Main.pas 유닛이 나타납니다.

- Main.pas 파일을 열고 implementation 섹션의 uses 절을 찾아가십시오. CustRpt 유닛이 포함되어 있을 것입니다.

*에러 인사이트(Error Insight)가 자동으로 이 유닛과 OrderRpt, InvcRpt 유닛을 잘못된 것으로 표시해주는 것을 주목하십시오. (컴파일러가 해당 유닛 이름들을 해결하지 못했다는 뜻입니다)

Cannot resolve unit names- plus other uncompilable code

- Ctrl+/ 키를 눌러 CustRpt, OrderRpt, InvcRpt 유닛을 주석 처리합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

다음 에러는 PrintCustomerReport 메소드에서 나타납니다.

- PrintCustomerReport 메소드 안의 코드를 선택하고 주석 처리합니다. (더 많이 주석으로 처리하거나 더 적게 하거나 관계없습니다)

procedure TMainForm.PrintCustomerReport(Preview: Boolean);
begin

  with MastData.CustByLastInvQuery do
  begin
    Open;
//    if Preview then
//       CustomerByInvoiceReport.Preview
//    else
//       CustomerByInvoiceReport.Print;
    Close;
  end;
end;

다음 문제는 PrintOrderReport 메소드에서 나타납니다. 역시 주석으로 처리합니다.

- PrintOrderReport 메소드 안의 코드들을 선택하고 Ctrl+/ 키를 눌러 주석으로 처리합니다.

PrintOrderReport in comments

이제 PrintInvoiceReport 한 군데만 남았습니다.

- PrintInvoiceReport 메소드 안의 코드들을 선택하고 주석으로 처리합니다. (더 많이 주석으로 처리하거나 더 적게 하거나 관계없습니다)

procedure TMainForm.PrintInvoiceReport(Preview: Boolean);
begin
  if PickOrderNoDlg.ShowModal = mrOk then
//     if Preview then
//        InvoiceByOrderNoReport.Preview
//     else
//        InvoiceByOrderNoReport.Print;
end;

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

이제, 프로젝트의 컴파일과 링크가 아무런 문제 없이 완료됩니다.

약간 주의를 해야 할 문제가 하나 더 있습니다. 지금 애플리케이션을 실행시키면, 제대로 동작할 수도 있지만 데이터베이스를 찾을 수 없다는 메시지를 받을 수도 있습니다.

이 마지막 문제는 애플리케이션의 코드 자체 때문에 발생하는 것입니다. 데이터모듈 안에 DataDirectory라는 함수가 있는데, 다음과 같이 정의되어 있습니다.

function TMastData.DataDirectory: string;
begin
  { Assume data is in ..\..\..\..\..\Common Files\Borland Shared\DATA\data relative to where we are }
  Result := ExtractFilePath(ParamStr(0));
  //Result := ExpandFileName(Result + '..\..\DATA\');
  Result := ExpandFileName(Result + '..\..\..\..\..\Common Files\Borland Shared\DATA\');
end;

주석의 내용대로, 데이터가 애플리케이션의 경로로부터 상대 경로로 ..\..\..\..\..\Common Files\Borland Shared\DATA\data 디렉토리에 있다고 가정하는 것입니다. 이것은 Demo 디렉토리 구조에서는 동작할 수 있겠지만, 애플리케이션을 배포했을 때 이용할 위치와는 관계가 없습니다.

사실, 이 프로젝트를 마이그레이션하기 시작할 때 데이터베이스가 디자인타임에 연결된다는 것을 확인했습니다. 따라서 Database.DatabaseName은 이미 정확한 위치를 가리키고 있습니다.

DataDirectory 함수는 단 한 군데에서만 이용되는데, 그것은 MastDataCreate 함수입니다. 우리는 거기서 하는 작업을 되돌리면 됩니다.

- datamod.pas 유닛을 열고 MastDataCreate 메소드를 찾습니다. DataFile 변수에 Database.DatabaseName의 값을 대입하여 DataDirectory 값을 덮어쓰도록 합니다.

procedure TMastData.MastDataCreate(Sender: TObject);
var
  DataFile: string;
begin
  DataFile := DataDirectory + 'MASTSQL.GDB';
  DataFile := Database.DatabaseName; // already working at design-time!
  if not FileExists(DataFile) then
    if MessageDlg('Could not locate MASTSQL.GDB.  Would you like to locate the file?',
    mtError, [mbYes, mbNo], 0) = mrYes then
      if OpenDialog.Execute then
      begin
        if UpperCase(ExtractFileName(OpenDialog.FileName)) = 'MASTSQL.GDB' then
          DataFile := OpenDialog.FileName
        else
          raise Exception.Create('Invalid File: ' + OpenDialog.FileName);
      end
      else
        raise Exception.Create('Cannot locate Interbase data file: MASTSQL.GDB');
  Database.DatabaseName := DataFile;
  Database.Open;
  Transaction.StartTransaction;
end;

*DataDirectory 호출을 없애버릴 수도 있습니다만, 어쨌든 DataFile에 새 값을 대입해야 합니다.

- Shift+F2 키를 눌러 프로젝트의 모든 파일들을 저장하고 다음으로 Shift+F9 키를 눌러 프로젝트를 리빌드합니다.

프로젝트는 다시 컴파일되고 실행되어 다음과 같이 Marine Adventures Order Entry 애플리케이션을 보여줄 것입니다.

Marine Adventures Order Entry 메인 애플리케이션

- Order 폼을 보이기 위해 New Order 버튼을 클릭합니다.

Order 폼

- Order 폼을 닫고 Orders by Customer 폼을 보이기 위해 Browse 버튼을 클릭합니다.

Orders by Customer 폼

- Orders by Customer 폼을 닫고 Browse Parts 폼을 보이기 위해 Parts 버튼을 클릭합니다.

Browse Parts 폼

- Browse Parts 폼을 닫고 Report Selection 폼을 보이기 위해 Reports 버튼을 클릭합니다.

Report Selection 폼

*세개의 레포트 모두 사용할 수 없으며 버튼들도 동작하지 않습니다. 이것은 우리가 모든 QuickReports를 이용하는 코드를 주석으로 처리했기 때문입니다. 원한다면 여러분이 직접 레포트를 추가할 수 있을 것입니다.