다른 클래스의 Private나 Protected 영역을 사용하려면 같은 유닛에 있어야 한다는 것은 아실 겁니다.
이런 것을 Friend Class라고 부릅니다.

  "우린 친구 아니가?"

친구끼리 감추는 거 없습니다 ㅡ.ㅡ;

그런데, 가끔 클래스를 설계하다보면 여러 클래스의 상호작용이 필요하고
상호 작용으로 인해 서로의 메소드를 사용하게 되는데,
실제 사용할 때는 이 메소드를 집적 접근하지 못하도록 막고 싶을 때가 있습니다.

이럴 땐 가장 쉽게 생각할 수 있는 것은 같은 유닛에 클래스를 밀어 넣는 것입니다.
이것은 제가 별로 안좋아하는 방식입니다.
소스의 가독성이 상당히 떨어지기 때문입니다.

두 번째는 Facade 패턴을 이용하는 것입니다.
지금은 팁을 작성하는 중이니 디자인 패턴의 대한 설명은 나중으로 미루겠습니다 ㅡ.ㅡ;

이제 남은 방법은 델파이 문법에는 존재하지 않는 Friend Class를 작성하는 것입니다.

상황은 이렇습니다.
TClass2에서 TClass1의 Protected 메소드인 doSomething을 사용하고자 합니다.

unit Class1; 

interface

uses
  Classes, Dialogs;

type
  TClass1 = class(Tobject)
  private
  protected
    Procedure doSomething;
  public
  end;

implementation

{ TClass1 }

procedure TClass1.doSomething;
begin
  ShowMessage('Hi');
end;
 
end.

이제 다른 Unit에 TClass2를 작성하여 TClass1의 doSonething 메소드를 호출하겠습니다.

unit Class2;

interface

uses
  Classes;

type
  TClass2 = class(Tobject)
  private
    Class1 : TObject;
  public
    Constructor Create(Class1:TObject);
    Procedure Test;
  end;

implementation

uses
  Class1;

type
  TFriendClass = class(TClass1)
  end;

{ TClass2 }

constructor TClass2.Create(Class1: TObject);
begin
  Self.Class1:= Class1;
end;
 
procedure TClass2.Test;
begin
  TFriendClass(Class1).doSomething;
end;

end.

그렇습니다.
TClass1의 Protected 영역을 집적 접근할 수 없기 때문에 TFriendClass가 TClass1을 상속받고
TFriendClass의 선언은 TClass2와 같은 유닛에 있기 때문에
이제 TFriendClass의 Protected 메소드인 doSomething에 접근할 수가 있는 것입니다.

Private 메소드는 당연히 안됩니다.
상속받을 수 없기 때문입니다.